AWS経験者もハマる！Terraformで学ぶさくらのクラウドとcloud-initの罠

./
├── secrets.auto.tfvars      # パスワードなどの機密情報を記述
├── database.tf              # データベースリソース
├── global.tf                # DNSリソース
├── network.tf               # ネットワークリソース
├── server.tf                # サーバーリソース
├── terraform.tf             # Terraform全体の設定
└── variables.tf             # 変数定義

Copy

# terraform.tf
terraform {
  required_version = ">= 1.11" # versionは適宜変更してください

  required_providers {
    sakuracloud = {
      source  = "sacloud/sakuracloud"
      version = "2.28.1"
    }
  }

  backend "s3" {
    bucket = "tfstate-file"
    key    = "simple.tfstate"
    endpoints = {
      s3 = "https://s3.isk01.sakurastorage.jp"
    }
    region                       = "jp-north-1"
    profile                      = "terraform-s3"
    shared_credentials_files     = ["../hogehoge/.accesskey"] # 自身の環境に合わせてください
    skip_requesting_account_id   = true
    skip_credentials_validation  = true
    skip_region_validation       = true
    skip_metadata_api_check      = true
    skip_s3_checksum             = true
  }
}

provider "sakuracloud" {
  profile = "default"
}

Copy

# network.tf
resource "sakuracloud_switch" "switch_simple" {
  name        = "switch_simple"
  description = "シンプル構成のスイッチ"
  tags        = ["sakura", "Simple"]
}

resource "sakuracloud_packet_filter" "filter_simple" {
  name = "filter_simple"
}

resource "sakuracloud_packet_filter_rules" "filter_rule_simple" {
  packet_filter_id = sakuracloud_packet_filter.filter_simple.id

  // SSH許可 (IPはサンプルです)
  expression {
    protocol         = "tcp"
    allow            = true
    source_network   = "<IPアドレス>"
    destination_port = "22"
  }
  // HTTP許可
  expression {
    protocol         = "tcp"
    allow            = true
    source_network   = "<IPアドレス>"
    destination_port = "80"
  }
  // HTTPS許可
  expression {
    protocol         = "tcp"
    allow            = true
    source_network   = "<IPアドレス>"
    destination_port = "443"
  }
  // その他は拒否
  expression {
    protocol = "ip"
    allow    = false
  }
}

Copy

# server.tf
data "sakuracloud_archive" "ubuntu" {
  filter {
    tags = [
      "cloud-init",      # <- このタグが重要！
      "distro-ubuntu",
    ]
  }
}

resource "sakuracloud_disk" "disk_simple" {
  name              = "disk_simple"
  description       = "シンプル構成のブロックストレージ"
  tags              = ["sakura", "Simple"]
  size              = 40
  plan              = "ssd"
  connector         = "virtio"
  source_archive_id = data.sakuracloud_archive.ubuntu.id
}

resource "sakuracloud_server" "server_simple" {
  name        = "server_simple"
  description = "シンプル構成のサーバー"
  tags        = ["sakura", "Simple"]
  disks       = [sakuracloud_disk.disk_simple.id]
  core        = 2
  memory      = 4

  network_interface {
    upstream         = "shared"
    packet_filter_id = sakuracloud_packet_filter.filter_simple.id
  }

  network_interface {
    upstream        = sakuracloud_switch.switch_simple.id
    user_ip_address = "128.0.0.1"
  }

  user_data = <<-EOF
    #cloud-config
    hostname: example.com
    manage_etc_hosts: true
    password: ${var.server_password}
    chpasswd: 
      expire: false
    ssh_pwauth: true
    lock_passwd: false
    write_files:
      - path: /var/www/html/index.html
        permissions: '0644'
        owner: www-data:www-data
        content: |
          Hello, World!
    package_update: true
    package_upgrade: true
    packages:
      - apache2
    runcmd:
      - systemctl enable apache2
      - systemctl start apache2
  EOF
}

Copy

# database.tf
resource "sakuracloud_database" "simple_db" {
  name          = "db_simple"
  description   = "シンプル構成のデータベース"
  tags          = ["sakura", "Simple"]
  database_type = "mariadb"
  plan          = "30g"
  username      = "dbuser"
  password      = var.database_password

  network_interface {
    switch_id     = sakuracloud_switch.switch_simple.id
    ip_address    = "128.0.11.10"
    netmask       = 24
    gateway       = "128.0.11.1"
    port          = 3306
    source_ranges = ["128.0.0.1/32"]
  }
}

Copy

# global.tf
resource "sakuracloud_dns" "main" {
  zone        = "example.com"
  description = "シンプル構成のDNS"
  tags        = ["sakura", "Simple"]

  depends_on = [
    sakuracloud_server.server_simple
  ]
}

resource "sakuracloud_dns_record" "web" {
  dns_id = sakuracloud_dns.main.id
  name   = "@"
  type   = "A"
  value  = sakuracloud_server.server_simple.ip_address
  ttl    = 300
}

Copy

# variables.tf
variable "server_password" {
  type      = string
  sensitive = true
}

variable "database_password" {
  type      = string
  sensitive = true
}

Copy

# secrets.auto.tfvars
server_password   = "your_secure_password"
database_password = "your_secure_db_password"

Copy

# server.tf (問題のあったコード)
data "sakuracloud_archive" "ubuntu" {
  filter {
    tags = ["distro-ubuntu"] # ← Ubuntuであることしか指定していなかった
  }
}

Copy

# server.tf (修正後のコード)
data "sakuracloud_archive" "ubuntu" {
  filter {
    tags = [
      "cloud-init",      # これを追加！
      "distro-ubuntu",
    ]
  }
}

Copy